WC3 JASS.com
"The Jass Vault" plus vJASS and Zinc

Magtheridon96 · **on:** January 11, 2012, 01:29:53 PM

Instead of using your own forces and triggers to fire code and boolexprs, you can use this library.
It doesn't even affect efficiency! You can queue codes/boolexprs instead of firing them if you're going
to need to run a lot of code. That's only one Trigger Evaluation per X amount of code where X is >9000.

Code: jass

/***********************************************
*
*   FireCode
*   v2.0.1.1
*   By Magtheridon96
*
*   - Executes Codes and Boolexprs
*
*   Note:
*   -----
*
*       - You must never use EnqueueCode/EnqueueCondition without 
*         calling NewCodeQueue/NewConditionQueue.
*       - Firing a Queue destroys it.
*
*   API:
*   ----
*
*       - function FireCode takes code c returns nothing
*           - Executes a code.
*       - function NewCodeQueue takes nothing returns nothing
*           - Creates a new code queue.
*       - function EnqueueCode takes code c returns nothing
*           - Enqueues a code.
*       - function FireCodeQueue takes nothing returns nothing
*           - Fires all queued codes.
*       - function FireCondition takes boolexpr b returns boolean
*           - Fires a boolexpr.
*       - function NewConditionQueue takes nothing returns nothing
*           - Creates a new boolexpr queue.
*       - function EnqueueCondition takes boolexpr b returns nothing
*           - Enqueues a boolexpr.
*       - function FireConditionQueue takes nothing returns boolean
*           - Fires all queued boolexprs.
*
*   SpeedFreak API:
*   ---------------
*
*       - //!textmacro FIRE_CODE takes code
*           - Executes a code.
*       - //!textmacro FIRE_CONDITION takes boolexpr
*
*       - //!textmacro NEW_CODE_QUEUE
*           - Creates a new code queue.
*       - //!textmacro ENQUEUE_CODE takes code
*           - Enqueues a code.
*       - //!textmacro FIRE_CODE_QUEUE
*           - Fires all queued codes.
*
*       - //!textmacro NEW_CONDITION_QUEUE
*           - Creates a new boolexpr queue.
*       - //!textmacro ENQUEUE_CONDITION takes boolexpr
*           - Enqueues a boolexpr.
*       - //!textmacro FIRE_CONDITION_QUEUE
*           - Fires all queued boolexprs.
*
***********************************************/
library FireCode
 
    globals
        public trigger array btQ
        public trigger array ctQ
        public integer bi = 0
        public integer ci = 0
        public trigger t = CreateTrigger()
    endglobals
    
    function FireCode takes code c returns nothing
        call ForForce(bj_FORCE_PLAYER[0], c)
    endfunction
    
    function NewCodeQueue takes nothing returns nothing
        set ci = ci + 1
        if ctQ[ci] == null then
            set ctQ[ci] = CreateTrigger()
        endif
    endfunction
    
    function EnqueueCode takes code c returns nothing
        call TriggerAddCondition(ctQ[ci], Filter(c))
    endfunction
    
    function FireCodeQueue takes nothing returns nothing
        call TriggerEvaluate(ctQ[ci])
        call TriggerClearConditions(ctQ[ci])
        set ci = ci - 1
    endfunction
    
    function FireCondition takes boolexpr b returns nothing
        // Do not change the order of these.
        // That would kill recursion-safety.
        call TriggerClearConditions(t)
        call TriggerAddCondition(t, b)
        call TriggerEvaluate(t)
    endfunction
    
    function NewConditionQueue takes nothing returns nothing
        set bi = bi + 1
        if btQ[bi] == null then
            set btQ[bi] = CreateTrigger()
        endif
    endfunction
    
    function EnqueueCondition takes boolexpr b returns nothing
        call TriggerAddCondition(btQ[bi], b)
    endfunction
    
    function FireConditionQueue takes nothing returns nothing
        call TriggerEvaluate(btQ[bi])
        call TriggerClearConditions(btQ[bi])
        set bi = bi - 1
    endfunction
    
    /* For Speedfreaks/Nestharus: */
    
        //! textmacro FIRE_CODE takes code
            call ForForce(bj_FORCE_PLAYER[0], $code$)
        //! endtextmacro
        
        //! textmacro NEW_CODE_QUEUE
            set FireCode_ci = FireCode_ci + 1
            if FireCode_ctQ[FireCode_ci] == null then
                set FireCode_ctQ[FireCode_ci] = CreateTrigger()
            endif
        //! endtextmacro
        
        //! textmacro ENQUEUE_CODE takes code
            call TriggerAddCondition(FireCode_ctQ[FireCode_ci], Filter($code$))
        //! endtextmacro
        
        //! textmacro FIRE_CODE_QUEUE
            call TriggerEvaluate(FireCode_ctQ[FireCode_ci])
            call TriggerClearConditions(FireCode_ctQ[FireCode_ci])
            set FireCode_ci = FireCode_ci - 1
        //! endtextmacro
        
        //! textmacro FIRE_CONDITION takes boolexpr
            call TriggerClearConditions(FireCode_t)
            call TriggerAddCondition(FireCode_t, $boolexpr$)
            call TriggerEvaluate(FireCode_t)
        //! endtextmacro
        
        //! textmacro NEW_CONDITION_QUEUE
            set FireCode_bi = FireCode_bi + 1
            if FireCode_btQ[FireCode_bi] == null then
                set FireCode_btQ[FireCode_bi] = CreateTrigger()
            endif
        //! endtextmacro
        
        //! textmacro ENQUEUE_CONDITION takes boolexpr
            call TriggerAddCondition(FireCode_btQ[FireCode_bi], $boolexpr$)
        //! endtextmacro
        
        //! textmacro FIRE_CONDITION_QUEUE
            call TriggerEvaluate(FireCode_btQ[FireCode_bi])
            call TriggerClearConditions(FireCode_btQ[FireCode_bi])
            set FireCode_bi = FireCode_bi - 1
        //! endtextmacro
    
endlibrary

Feel free to comment.

Magtheridon96 · **Reply #1 on:** January 17, 2012, 08:26:18 PM

Updated to the latest version: Fixed Boolexpr execution bug.

moyack · **Reply #2 on:** January 18, 2012, 03:14:06 PM

Hmm intersting for one thing I'm doing in my map...

I'd like to ppost my problem here in order to not make this offtopic.

Troll-Brain · **Reply #3 on:** August 02, 2012, 12:24:14 PM

gogo graveyard ?

moyack · **Reply #4 on:** August 02, 2012, 08:08:50 PM

Quote from: Troll-Brain on August 02, 2012, 12:24:14 PM

gogo graveyard ?

Why?? it has some stuff that could be useful

Troll-Brain · **Reply #5 on:** August 02, 2012, 09:23:56 PM

I will let Mag talk more about that, but in short, either use functions interfaces or inline your own way to fire code.

Magtheridon96 · **Reply #6 on:** August 05, 2012, 09:52:30 AM

Ah yes, this should be graveyarded

Honestly, I decided it's trash a very long time ago XD

sankaku · **Reply #7 on:** August 31, 2015, 02:37:21 AM

I do not see example code so I will not attempt to use because I do not understand what it is trying to do. Funny how so many people think they can just type up some API for the function and expect people know what to do with it.