WC3 JASS.com
"The Jass Vault" plus vJASS and Zinc

Magtheridon96 · **on:** July 09, 2012, 01:29:49 PM

I'm attempting to start up some activity over here by posting/spamming resources

.

This system was made to replace that cumbersome GTrigger by Jesus4Lyf.
Special thanks to Bribe, azlier and BBQ. (The most awesome people I know /o/)

Code: jass

/**************************************************************
*
*   RegisterPlayerUnitEvent
*   v5.1.0.1
*   By Magtheridon96
*
*   I would like to give a special thanks to Bribe, azlier
*   and BBQ for improving this library. For modularity, it only 
*   supports player unit events.
*
*   Functions passed to RegisterPlayerUnitEvent must either
*   return a boolean (false) or nothing. (Which is a Pro)
*
*   Warning:
*   --------
*
*       - Don't use TriggerSleepAction inside registered code.
*       - Don't destroy a trigger unless you really know what you're doing.
*
*   API:
*   ----
*
*       - function RegisterPlayerUnitEvent takes playerunitevent whichEvent, code whichFunction returns nothing
*           - Registers code that will execute when an event fires.
*       - function RegisterPlayerUnitEventForPlayer takes playerunitevent whichEvent, code whichFunction, player whichPlayer returns nothing
*           - Registers code that will execute when an event fires for a certain player.
*       - function GetPlayerUnitEventTrigger takes playerunitevent whichEvent returns trigger
*           - Returns the trigger corresponding to ALL functions of a playerunitevent.
*
**************************************************************/
library RegisterPlayerUnitEvent // Special Thanks to Bribe and azlier
    globals
        private trigger array t
    endglobals
    
    function RegisterPlayerUnitEvent takes playerunitevent p, code c returns nothing
        local integer i = GetHandleId(p)
        local integer k = 15
        if t[i] == null then
            set t[i] = CreateTrigger()
            loop
                call TriggerRegisterPlayerUnitEvent(t[i], Player(k), p, null)
                exitwhen k == 0
                set k = k - 1
            endloop
        endif
        call TriggerAddCondition(t[i], Filter(c))
    endfunction
    
    function RegisterPlayerUnitEventForPlayer takes playerunitevent p, code c, player pl returns nothing
        local integer i = 16 * GetHandleId(p) + GetPlayerId(pl)
        if t[i] == null then
            set t[i] = CreateTrigger()
            call TriggerRegisterPlayerUnitEvent(t[i], pl, p, null)
        endif
        call TriggerAddCondition(t[i], Filter(c))
    endfunction
    
    function GetPlayerUnitEventTrigger takes playerunitevent p returns trigger
        return t[GetHandleId(p)]
    endfunction
endlibrary

Here's a vanilla Jass version:

Code: jass

//**************************************************************
//*
//*   RegisterPlayerUnitEvent (Vanilla Jass)
//*   v5.1.0.1
//*   By Magtheridon96
//*
//*   I would like to give a special thanks to Bribe, azlier
//*   and BBQ for improving this library. For modularity, it only 
//*   supports player unit events.
//*
//*   Functions passed to RegisterPlayerUnitEvent must either
//*   return a boolean (false) or nothing. (Which is a Pro)
//*
//*   Implementation:
//*   ---------------
//*
//*       - Copy all this script into a new trigger called "RegisterPlayerUnitEvent Jass"
//*       - Create a trigger array variable called RPUE.
//*       - Done.
//*
//*   Warning:
//*   --------
//*
//*       - Don't use TriggerSleepAction inside registered code.
//*       - Don't destroy a trigger unless you really know what you're doing.
//*
//*   API:
//*   ----
//*
//*       - function RegisterPlayerUnitEvent takes playerunitevent whichEvent, code whichFunction returns nothing
//*           - Registers code that will execute when an event fires.
//*       - function RegisterPlayerUnitEventForPlayer takes playerunitevent whichEvent, code whichFunction, player whichPlayer returns nothing
//*           - Registers code that will execute when an event fires for a certain player.
//*       - function GetPlayerUnitEventTrigger takes playerunitevent whichEvent returns trigger
//*           - Returns the trigger corresponding to ALL functions of a playerunitevent.
//*
//**************************************************************
function RegisterPlayerUnitEvent takes playerunitevent p, code c returns nothing
    local integer i = GetHandleId(p)
    local integer k = 15
    if udg_RPUE[i] == null then
        set udg_RPUE[i] = CreateTrigger()
        loop
            call TriggerRegisterPlayerUnitEvent(udg_RPUE[i], Player(k), p, null)
            exitwhen k == 0
            set k = k - 1
        endloop
    endif
    call TriggerAddCondition(udg_RPUE[i], Filter(c))
endfunction
 
function RegisterPlayerUnitEventForPlayer takes playerunitevent p, code c, player pl returns nothing
    local integer i = 16 * GetHandleId(p) + GetPlayerId(pl)
    if udg_RPUE[i] == null then
        set udg_RPUE[i] = CreateTrigger()
        call TriggerRegisterPlayerUnitEvent(udg_RPUE[i], pl, p, null)
    endif
    call TriggerAddCondition(udg_RPUE[i], Filter(c))
endfunction
 
function GetPlayerUnitEventTrigger takes playerunitevent p returns trigger
    return udg_RPUE[GetHandleId(p)]
endfunction
    
function InitTrig_RegisterPlayerUnitEvent_Jass takes nothing returns nothing
endfunction

Feel free to comment.

zerocool · **Reply #1 on:** July 14, 2012, 02:29:27 AM

When I use this:

Code: [Select]

RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_SPELL_EFFECT,function bla,bla)
everything is working properly

But when I use this:

Code: [Select]

RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function bla,bla)
spell/skill does not work.

Does anyone know what the problem is?!?

moyack · **Reply #2 on:** July 14, 2012, 06:08:34 AM

Quote from: zerocool on July 14, 2012, 02:29:27 AM

When I use this:
Code: jass
RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_SPELL_EFFECT,function bla,bla)

everything is working properly

But when I use this:
Code: jass
RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function bla,bla)

spell/skill does not work.

Does anyone know what the problem is?!?

Could you provide us with the spell code?

zerocool · **Reply #3 on:** July 14, 2012, 09:20:59 AM

Quote from: moyack on July 14, 2012, 06:08:34 AM

Could you provide us with the spell code?

Okay, no problem.

When I try to use this:

Code: jass

function SkillHeatActions takes nothing returns boolean
    // bla,bla
    return true
endfunction
 
function StartTrigger_Skill_Heat takes nothing returns nothing
    local trigger=CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_HERO_SKILL)
    call TriggerAddCondition(t,Condition(function SkillHeatActions))
    call Preload(H_ModelPath())
    set t=null
endfunction

Everything works perfectly,and when I try this

Code: jass

function SkillHeatActions takes nothing returns boolean
   // bla,bla
    return true
endfunction
 
function StartTrigger_Skill_Heat takes nothing returns nothing
    call RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function SkillHeatActions)
    call Preload(H_ModelPath())
endfunction

simply will not work...

moyack · **Reply #4 on:** July 14, 2012, 10:25:57 AM

Quote from: zerocool on July 14, 2012, 09:20:59 AM

Okay, no problem.

When I try to use this:
Code: jass
function SkillHeatActions takes nothing returns boolean
// bla,bla
return true
endfunction

function StartTrigger_Skill_Heat takes nothing returns nothing
local trigger=CreateTrigger()
call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_HERO_SKILL)
call TriggerAddCondition(t,Condition(function SkillHeatActions))
call Preload(H_ModelPath())
set t=null
endfunction

Everything works perfectly,and when I try this
Code: jass
function SkillHeatActions takes nothing returns boolean
// bla,bla
return true
endfunction

function StartTrigger_Skill_Heat takes nothing returns nothing
call RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function SkillHeatActions)
call Preload(H_ModelPath())
endfunction

simply will not work...

IS this function inside a scope? if so, try changing it into a library with the respective requirements

zerocool · **Reply #5 on:** July 14, 2012, 12:46:36 PM

Quote from: moyack on July 14, 2012, 10:25:57 AM

IS this function inside a scope? if so, try changing it into a library with the respective requirements

I think the problem is not what you said
For Example:When I use the event EVENT_PLAYER_UNIT_SPELL_EFFECT everything is working well,but when I want to use the event EVENT_PLAYER_HERO_SKILL then there is a problem,spell/skill will not work.

Which means that only that specific event causes error.

Because it is logical that, if this works

Code: jass

function StartTrigger_Skill_Heat takes nothing returns nothing
    local trigger=CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_HERO_SKILL)
    call TriggerAddCondition(t,Condition(function SkillHeatActions))
    call Preload(H_ModelPath())
    set t=null
endfunction

and this will not work

Code: jass

function StartTrigger_Skill_Heat takes nothing returns nothing
    call RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function SkillHeatActions)
    call Preload(H_ModelPath())
endfunction

that there is a conflict with the system
I think this event[EVENT_PLAYER_HERO_SKILL] has a conflict with the system

moyack · **Reply #6 on:** July 14, 2012, 04:39:42 PM

Hmmm.... have you debugged it??? I mean if this even start at all?? I hope you're not using TriggerSleepAction() or PolledWait() in the condition because it breaks the thread.

zerocool · **Reply #7 on:** July 14, 2012, 07:11:38 PM

Quote from: moyack on July 14, 2012, 04:39:42 PM

Hmmm.... have you debugged it??? I mean if this even start at all?? I hope you're not using TriggerSleepAction() or PolledWait() in the condition because it breaks the thread.

I never use TriggerSleepAction and PolledWait func

moyack · **Reply #8 on:** July 14, 2012, 07:22:24 PM

Quote from: zerocool on July 14, 2012, 07:11:38 PM

I never use TriggerSleepAction and PolledWait func

That's a relief

just in case... try my snippet to see if it's Mag's version.

zerocool · **Reply #9 on:** July 15, 2012, 11:55:39 AM

I have tested your system for some time, and the results are as follows:

RegisterAnyUnitEvent Condition:

Code: jass

function InitTrig_Skill_Heat takes nothing returns nothing
    call RegisterAnyUnitEvent(EVENT_PLAYER_HERO_SKILL,function HeatMainAct,null)
endfunction
 

1.Impression:Works perfectly.
2.Opinion:Very stable.
3.Errors:No errors found.

RegisterAnyUnitEvent Action:

Code: jass

function InitTrig_Skill_Heat takes nothing returns nothing
    call RegisterAnyUnitEvent(EVENT_PLAYER_HERO_SKILL,null,function HeatAddDamageAct)
endfunction
 

1.Impression:Works perfectly.
2.Opinion:Very stable.
3.Errors:No errors found.

RegisterAnyUnitEvent Condition/Action:

Code: jass

function InitTrig_Skill_Heat takes nothing returns nothing
    call RegisterAnyUnitEvent(EVENT_PLAYER_HERO_SKILL,function RegisterSkillHeat,function HeatMainAct)
endfunction
 

1.Impression:Works perfectly.
2.Opinion:Very stable.
3.Errors:No errors found.

TriggerRegisterAnyUnitEventBJ:

Code: jass

function InitTrig_Skill_Heat takes nothing returns nothing
    local trigger=CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_HERO_SKILL)
    call TriggerAddCondition(t,Condition(function HeatMainAct))
    set t=null
endfunction
 

1.Impression:Works perfectly.
2.Opinion:Stable.
3.Errors:No errors found.

RegisterPlayerUnitEvent:

Code: jass

function InitTrig_Skill_Heat takes nothing returns nothing
    call RegisterPlayerUnitEvent(EVENT_PLAYER_HERO_SKILL,function HeatMainAct)
endfunction
 

1.Impression:Not working properly.
2.Opinion:Very unstable,especially with "EVENT_PLAYER_HERO_SKILL".
3.Errors:Can cause errors.
4.Note: I still have not found the reason why this event["EVENT_PLAYER_HERO_SKILL"] in some cases,cause problems.

moyack · **Reply #10 on:** July 16, 2012, 06:54:19 AM

I need to get some time to test this event, but, meanwhile try to use the functions inside a library. I had that kind of issue in my project Power of Corruption and the problem was that I was using scopes, changing them into libraries solved the issues.