WC3 Modding Information Center
For your WC3 needs...

moyack · **on:** May 13, 2013, 01:01:13 PM

Evil Extirpation.
By Moyack
2013.

Description.

The Evil Messenger extirpates from the land itself all the power of Evil, luring from the void ancient spirits of Evil. Each of them would attack enemy units and, in the process, the evil from nearby enemy units is extracted from themselves, dealing some additional damage.

Level 1 - Deals additional 5 damage, lasts 15 seconds.
Level 2 - Deals additional 8 damage, lasts 20 seconds.
Level 3 - Deals additional 11 damage, lasts 25 seconds.

Video.

Requirements

Alloc2: https://wc3modding.info/5012/snippet-allocloop-aka-alloc-2/

Spell Code.

Code: jass

/* ==================================================
   ||           EVIL EXTIRPATION SPELL             ||
   ||                By moyackx                    ||
   ||               Version 1.0.                   ||
   ||                   2013                       ||
   ||         For the Zephyr Contest #10:          ||
   ||         What lies on the other side          ||
   ==================================================
   
   Description:
   ------------
   The Evil Messenger extirpates from the land itself 
   all the power of Evil, luring from the void ancient 
   spirits of Evil. Each of them would attack enemy 
   units and, in the process, the evil from nearby enemy 
   units is extracted from themselves, dealing some 
   additional damage.
   
   How To install:
   ---------------
   1. Copy & paste the "Evil Extirpation" ability, buff
      and effect in your map
   2. Copy this code in your map.
   3. Edit the CONFIGURATION PART with the new Ability
      (ABIL) and unit type summoned (SAUMMON) array. 
      Adjust the other values too. Don't forget to set 
      the ward classification to the summoned units, that
      will improve the eyecandy.
   4. Enjoy :D
   
   Don't forget this code requires Alloc2 to run
   properly. This code is in this test map or you can
   download it here:
   [url]https://wc3modding.info/5012/snippet-allocloop-aka-alloc-2/[/url]
*/
 
library EvilExtirpation initializer init requires Alloc
/* CONFIGURTATION PART */
globals
    private constant integer ABIL = 'A000' // the Ability rawcode
    private constant real    DT   = 0.3    // Sets the periodic Check Frecuency
    private constant real    AOE  = 700.   // Spell Area of Effect
    private constant real    MAXH = 2000.  // Maximum Height flight for spirit units
    private constant real    HRATE= 200.   // Sets the elevation rate
    private constant real    DDUR = 2.5    // Sets the duration of spirits
    private constant boolean ALOC = false  // Defines if we apply locust ability to the spirits
    
    private          integer array SUMMON // the spirit unit type array.
endglobals
 
private function SetSummons takes nothing returns nothing
    /* Here, you can set all the unit types your spell
       will have per level. If your maps has more spell
       levels, simply add  more in this code...
    */ 
    set SUMMON[1] = 'n001'
    set SUMMON[2] = 'n002'
    set SUMMON[3] = 'n003'
endfunction
/* END CONFIGURATION PART */
 
private struct data extends array
    static timer T = CreateTimer()
    static integer I = 0
    unit caster
    integer order
    
    implement AllocLoop
    
    method destroy takes nothing returns nothing
        set .caster = null
        set thistype.I = thistype.I - 1
        if thistype.I == 0 then
            call PauseTimer(thistype.T)
        endif
        call .deallocate()
    endmethod
    
    static method Loop takes nothing returns nothing
        local unit u
        implement loop
            set u = CreateUnit(GetOwningPlayer(this.caster), SUMMON[GetUnitAbilityLevel(this.caster, ABIL)], GetUnitX(this.caster) + GetRandomReal(-AOE, AOE), GetUnitY(this.caster) + GetRandomReal(-AOE, AOE), GetRandomReal(0, 360))
            call UnitAddType(u, UNIT_TYPE_SUMMONED) // so the summoned unit can have the effects from some dispelling spells...
            call DestroyEffect(AddSpellEffectById(ABIL, EFFECT_TYPE_TARGET, GetUnitX(u), GetUnitY(u)))
            call UnitAddAbility(u, 'Arav') // Add the storm Crow Form ability, to make it fly...
            call SetUnitFlyHeight(u, MAXH, HRATE)
            call UnitApplyTimedLife(u, 0, DDUR)
            if ALOC then
                call UnitAddAbility(u, 'Aloc')
            endif
            if this.order != GetUnitCurrentOrder(this.caster) then
                call this.destroy()
            endif
        implement endloop
        set u = null
    endmethod
    
    static method Start takes unit c returns thistype
        local thistype this = thistype.allocate()
        set this.caster = c
        set this.order = GetUnitCurrentOrder(c)
        set thistype.I = thistype.I + 1
        if thistype.I == 1 then
            call TimerStart(thistype.T, DT, true, function thistype.Loop)
        endif
        return this
    endmethod
endstruct
 
private function DoEffect takes nothing returns boolean
    if GetSpellAbilityId() == ABIL then
        call data.Start(GetTriggerUnit())
    endif
    return false
endfunction
 
private function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t, Condition(function DoEffect))
    set t = null
    call SetSummons()
endfunction
 
endlibrary

s[ub]lime · **Reply #1 on:** May 13, 2013, 07:23:08 PM

Shouldn't this be in the media boss?

moyack · **Reply #2 on:** May 14, 2013, 09:31:23 AM

Quote from: s[ub]lime on May 13, 2013, 07:23:08 PM

Shouldn't this be in the media boss?

In theory, yes. I'm working in passing the spells into actual threads, because this type of content requires much more text than a model/skin/icon resource.