WC3 Modding Information Center
For your WC3 needs...

AGD · **on:** August 22, 2016, 02:06:44 AM

ILLUSION EDITOR

This system provides users with helpful utilities with regards to creation of illusions as well as the manipulation of many of their aspects.
With this system, you can now create illusions of any type as easily as creating units. This even allows you to create permanent illusions.
Read the script header for more details.

Please give credits to the following people if you use this resource in your map.

Credits:
- AGD (Author)
- TriggerHappy (UnitDex)
- Looking_For_Help (PDDS)
- Bribe (table)
- Magtheridon96 (RegisterPlayerUnitEvent)
- Vexorian (TimerUtils)
- Rising_Dusk (GroupUtils)
- Alain.Mark (PlayerUtils)

Main Script

Code: jass

library IllusionEditor /*
 
 
  */requires /*
 
  */UnitDex /*
        http://www.hiveworkshop.com/threads/system-unitdex-unit-indexer.248209/
 
  */DamageEvent /*
        http://www.hiveworkshop.com/threads/system-physical-damage-detection.228456/
 
  */Table /*
        http://www.hiveworkshop.com/threads/snippet-new-table.188084/
 
  */optional RegisterPlayerUnitEvent /*
        http://www.hiveworkshop.com/threads/snippet-registerplayerunitevent.203338/
 
  */optional TimerUtils /*
        http://www.wc3c.net/showthread.php?p=1020244
 
  */optional GroupUtils /*
        http://www.wc3c.net/showthread.php?t=104464
 
  */optional PlayerUtils /*
        http://www.hiveworkshop.com/threads/snippet-playerutils.213620/
 
 
*///! novjass
 
     _______________________
    |                       |
    | Illusion Editor v1.3  |
    |    Written by AGD     |
    |_______________________|
 
/*     This system gives you freedom and ease in creating illusions. With this, you
     can now create illusions of any type as easily as creating units or make an
     illusion copy from an already existing unit, with the ability to change many
     of their aspects (such as duration, damage dealt, damage recieved, deathSFX,
     and hero level) dynamically.
 
 
     Hint:
         - Use zero or any negative value for duration to make a permanent illusion
         - Setting a hero illusion's level might cause a change to its proper name
 
     To Import:
         - Copy all the neccessary Object Editor data or alternatively use the object merger
         - Copy this trigger/trigger category together with the requirements
         - Configure the configurable object rawcodes
*/
    |=======|
    |  API  |
    |=======|
 
        function CreateIllusion takes player whichPlayer, integer ID, real dur, real damageDealt, real damageReceived, real x, real y, real angle returns unit/*
        - Creates an illusion of type <ID>
 
      */function CopyUnit takes player whichPlayer, unit u, real dur, real damageDealt, real damageReceived, real x, real y, real angle returns unit/*
        - Creates an illusion copy of a unit which possesses the same abilities and items as the original unit
 
      */function SetIllusionLevel takes unit u, integer level, boolean showEyeCandy returns boolean/*
        - Sets the level of the illusion to a desired value and returns boolean value depending on the success of the operation
          (Only works if the illusion is a hero and if it was created using this system)
 
      */function SetIllusionDuration takes unit u, real time returns boolean/*
        - Sets the duration of the illusion and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function AddIllusionDuration takes unit u, real extraTime returns boolean/*
        - Adds an extra duration to an illusion's timed life and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function SetIllusionDamageFactor takes unit u, real factor returns boolean/*
        - Sets the damagedealt factor of the illusion and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function SetIllusionReceiveFactor takes unit u, real factor returns boolean/*
        - Sets the damagereceivefactor of the illusion and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function ShowIllusionDeathEffect takes unit u, boolean flag returns boolean/*
        - Sets the illusion's death animation ON/OFF and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function SetIllusionDeathEffect takes unit u, string model returns boolean/*
        - Sets the death animation of the illusion and returns a boolean value depending on the success of the operation
          (This only works for illusions created by this system)
 
      */function GetIllusionElapsedTime takes unit u returns real/*
        - Returns the elapsed time of the illusion
          (This will return 0 for illusions not created by this system)
 
      */function GetIllusionRemainingDuration takes unit u returns real/*
        - Returns the remaining duration of the illusion
          (This will return 0 for illusions not created by this system)
 
      */function GetIllusionTotalDuration takes unit u returns real/*
        - Returns the duration of the illusion
          (This will return 0 for illusions not created by this system)
 
      */function GetIllusionDamageFactor takes unit u returns real/*
        - Returns the damagedealt factor of the illusion
          (This will return 0 for illusions not created by this system)
 
      */function GetIllusionReceiveFactor takes unit u returns real/*
        - Returns the damagereceive factor of the illusion
          (This will return 0 for illusions not created by this system)
 
      */function GetLastIllusion takes nothing returns unit/*
        - Returns the last illusion created using this system
 
      */function GetIllusionFlag takes unit u returns boolean/*
        - Checks if the illusion is created by this system or not
 
      */function IllusionDeathEvent takes code c returns nothing/*
        - Adds a code to run when an illusion created from this system dies
 
 
*///! endnovjass
 
 
    globals
 
        ///////////////////////////
        // Configuration Section //
        ///////////////////////////
 
        /////////////////////////////////////////////////////
        // Rawcode of the item used for creating illusions //
        /////////////////////////////////////////////////////
        private constant integer ITEM_ID = 'I000'
        /////////////////////////////////////////////////////
        // Rawcode of the dummy caster                     //
        /////////////////////////////////////////////////////
        private constant integer DUMMY_ID = 'i001'
        /////////////////////////////////////////////////////
        // Illusion timed life check interval              //
        /////////////////////////////////////////////////////
        private constant real LOOP_INTERVAL = 0.03125
        /////////////////////////////////////////////////////
        // Synchronize this value with the duration of     //
        // illusions produced by the the item in the       //
        // object editor so that this system will be able  //
        // to make the neccessary adjustments.             //
        // It would be better to set this value to 3600    //
        // which is the maximum duration you can put in    //
        // the object editor. But always be reminded that  //
        // everytime you change this value, change also    //
        // that of the object editor's!                    //
        /////////////////////////////////////////////////////
        private constant real ITEM_DUR_LIMIT = 5.00
        /////////////////////////////////////////////////////
        // The remaining time of the illusion before it    //
        // would be replaced with another one in case the  //
        // desired duration of the illusion is greater     //
        // than what the item could provide                //
        /////////////////////////////////////////////////////
        private constant real REPLACE_TIME_ALLOWANCE = 0.10
        /////////////////////////////////////////////////////
        // The default death animation of the illusions    //
        /////////////////////////////////////////////////////
        private constant string DEFAULT_DEATH_SFX = "Abilities\\Spells\\Orc\\MirrorImage\\MirrorImageDeathCaster.mdl"
        /////////////////////////////////////////////////////
        // The owning player of the dummy unit             //
        /////////////////////////////////////////////////////
        private constant player DUMMY_OWNER = Player(15)
        /////////////////////////////////////////////////////
        // The prefix of the operation error message when  //
        // debug mode is enabled                           //
        /////////////////////////////////////////////////////
        private constant string ERROR_PREFIX = "Operation Failed: "
 
        //////////////////////////
        // End of Configuration //
        //////////////////////////
 
    endglobals
 
 
    //===== Do not change anything below this line if you're not so sure on what you're doing =====//
    native UnitAlive takes unit u returns boolean
 
    private keyword S
 
    globals
 
        private HashTable hash
        private trigger deathEvent      = CreateTrigger()
        private trigger illuDeathTrig   = null
        private integer index           = 0
        private integer tempInt         = 0
        private integer usedDeathEvent  = 0
        private real illusionDeathEvent = 0.00
        private unit illusion
        private unit U
        private unit dummyCaster
        private item casterItem
        private player localPlayer
        private filterfunc deathHandler
        private code durationUpdater
 
        // These variables are used to store unit specific data for each illusion created using this system
        private integer array maxTargeterCount
        private integer array order
        private integer array orderType
        private boolean array flag
        private boolean array check
        private boolean array showDeath
        private real array targPointX
        private real array targPointY
        private unit array orderTarget
        private real array elapsed
        private real array duration
        private real array damageFactor
        private real array receiveFactor
        private real array X
        private real array Y
        private real array facing
        private player array owner
        private string array deathSFX
 
    endglobals
 
    static if DEBUG_MODE then
        private function Debug takes string msg returns nothing
            call DisplayTimedTextToPlayer( localPlayer, 0, 0, 30, "|CFFFFCC00[Illusion Editor]|R  " + msg )
        endfunction
    endif
 
 
    ///////////////////////////////////////////////////
    // These three functions caches the order of the //
    // expiring illusion units to be passed to their //
    // replacements. Similarly when the expiring     //
    // illusion is targeted with an order, the order //
    // will be redirected to its replacement as well.//
    ///////////////////////////////////////////////////
    private function CacheTargetOrder takes nothing returns nothing
        local unit u = GetOrderedUnit()
        local unit t = GetOrderTargetUnit()
        local integer i = GetUnitId( u )
        local integer tDex = GetUnitId( t )
        if check[i] then
            set orderType[i] = 1
            set orderTarget[i] = t
        endif
        if check[tDex] then
            set order[i] = GetUnitCurrentOrder( u )
            if not flag[i] then
                loop
                    set maxTargeterCount[tDex] = maxTargeterCount[tDex] + 1
                    if hash[tDex].unit[maxTargeterCount[tDex]] == null then
                        set hash[tDex].unit[maxTargeterCount[tDex]] = u
                        set flag[i] = true
                        break
                    endif
                endloop
            endif
        endif
        set u = null
        set t = null
    endfunction
 
    private function CachePointOrder takes nothing returns nothing
        local integer i = GetUnitId( GetOrderedUnit() )
        set flag[i] = false
        if check[i] then
            set orderType[i] = 2
            set targPointX[i] = GetOrderPointX()
            set targPointY[i] = GetOrderPointY()
        endif
    endfunction
 
    private function CacheOrder takes nothing returns nothing
        local integer i = GetUnitId( GetOrderedUnit() )
        set flag[i] = false
        if check[i] then
            set orderType[i] = 3
        endif
    endfunction
 
 
    ///////////////
    // On Summon //
    ///////////////
    private function OnSummon takes nothing returns nothing
        local timer t
        local integer i
        local integer uDex
        if GetSummoningUnit() == dummyCaster then
            set i = GetUnitId( dummyCaster )
            set U = GetTriggerUnit()
            set uDex = GetUnitId( U )
            set check[uDex] = true
            set showDeath[uDex] = true
            set duration[uDex] = duration[i]
            set damageFactor[uDex] = damageFactor[i]
            set receiveFactor[uDex] = receiveFactor[i]
            set owner[uDex] = owner[i]
            set deathSFX[uDex] = DEFAULT_DEATH_SFX
            set elapsed[uDex] = 0
            set maxTargeterCount[uDex] = 0
            static if LIBRARY_TimerUtils then
                set t = NewTimer()
            else
                set t = CreateTimer()
            endif
            set hash[GetHandleId( t )].unit[0] = U
            call TimerStart( t, LOOP_INTERVAL, true, durationUpdater )
            call SetUnitOwner( U, owner[i], true )
            call SetUnitFacing( U, facing[i] )
            if IsUnitType( U, UNIT_TYPE_STRUCTURE ) then
                call SetUnitPosition( U, X[i], Y[i] )
            else
                call SetUnitX( U, X[i] )
                call SetUnitY( U, Y[i] )
            endif
            call TriggerRegisterUnitStateEvent( deathEvent, U, UNIT_STATE_LIFE, LESS_THAN, UNIT_MIN_LIFE )
            set t = null
        endif
    endfunction
 
 
    //! textmacro CREATOR takes FUNC, TAKE, X, TARGET
    private function $FUNC$ takes player whichPlayer, $TAKE$, real dur, real damageDealt, real damageReceived, real x, real y, real angle returns unit
        local integer i = GetUnitId( dummyCaster )
        $X$local unit tempUnit = CreateUnit( DUMMY_OWNER, ID, x, y, angle )
        if dur < 0 then
            set dur = 0
        endif
        if damageDealt < 0 then
            set damageDealt = 0
        endif
        if damageReceived < 0 then
            set damageReceived = 0
        endif
        set X[i] = x
        set Y[i] = y
        set duration[i] = dur
        set damageFactor[i] = damageDealt
        set receiveFactor[i] = damageReceived
        set facing[i] = angle
        set owner[i] = whichPlayer
        call UnitUseItemTarget( dummyCaster, casterItem, $TARGET$ )
        $X$call RemoveUnit( tempUnit )
        $X$set tempUnit = null
        return U
    endfunction
    //! endtextmacro
    //! runtextmacro CREATOR( "Create", "integer ID", "", "tempUnit" )
    //! runtextmacro CREATOR( "Copy", "unit u", "//", "u" )
 
 
    /////////////////////////////////////////////////
    // This function controls the duration of the  //
    // illusions as well as replacing them in case //
    // their hardcoded lifetime expires before     //
    // meeting the duration desired for them       //
    /////////////////////////////////////////////////
    private function AdjustTimedLife takes nothing returns nothing
        local timer t      = GetExpiredTimer()
        local unit u       = hash[GetHandleId( t )].unit[0]
        local integer i    = GetUnitId( u )
        local integer lastOrder
        local unit new
        local real toAdd
        if UnitAlive( u ) and u != null then
            set elapsed[i] = elapsed[i] + LOOP_INTERVAL
            if duration[i] < ITEM_DUR_LIMIT and ( ( duration[i] > 0 and elapsed[i] >= duration[i] ) or duration[i] < 0.00 ) then
                call hash.remove( GetHandleId( t ) )
                call RemoveUnit( u )
                static if LIBRARY_TimerUtils then
                    call ReleaseTimer( t )
                else
                    call DestroyTimer( t )
                endif
            elseif elapsed[i] >= ITEM_DUR_LIMIT - REPLACE_TIME_ALLOWANCE then
                set toAdd = duration[i] - ( ITEM_DUR_LIMIT - REPLACE_TIME_ALLOWANCE )
                if toAdd < 0 then
                    set toAdd = 0
                endif
                set lastOrder = GetUnitCurrentOrder( u )
                set new = Copy( owner[i], u, toAdd, damageFactor[i], receiveFactor[i], GetUnitX( u ), GetUnitY( u ), GetUnitFacing( u ) )
                //! textmacro REDIRECTDATA takes KEY, NEWLIFE, NEWMANA
                call ShowUnit( u, false )
                call SetWidgetLife( new, $NEWLIFE$ )
                call SetUnitState( new, UNIT_STATE_MANA, $NEWMANA$ )
                set index = 0
                loop
                    set index = index + 1
                    set U = hash[$KEY$].unit[index]
                    set tempInt = GetUnitId( U )
                    if U != null and flag[tempInt] then
                        set flag[tempInt] = false
                        call IssueTargetOrderById( U, order[tempInt], new )
                    endif
                    exitwhen index > maxTargeterCount[i]
                endloop
                if orderType[i] == 1 then
                    call IssueTargetOrderById( new, lastOrder, orderTarget[i] )
                elseif orderType[i] == 2 then
                    call IssuePointOrderById( new, lastOrder, targPointX[i], targPointY[i] )
                elseif orderType[i] == 3 then
                    call IssueImmediateOrderById( new, lastOrder )
                endif
                if IsUnitSelected( u, localPlayer ) then
                    call SelectUnit( new, true )
                endif
                set maxTargeterCount[i] =  0
                set index = GetUnitId( new )
                set deathSFX[index] = deathSFX[i]
                set showDeath[index] = showDeath[i]
                //! endtextmacro
                //! runtextmacro REDIRECTDATA( "i", "GetWidgetLife( u )", "GetUnitState( u, UNIT_STATE_MANA )" )
                call hash.remove( GetHandleId( t ) )
                set showDeath[i] = false
                call RemoveUnit( u )
                static if LIBRARY_TimerUtils then
                    call ReleaseTimer( t )
                else
                    call DestroyTimer( t )
                endif
                if u == illusion then
                    set illusion = new
                endif
                set new = null
            endif
        endif
        set t = null
        set u = null
    endfunction
 
 
    /////////////////////////////////
    // Public APIs                 //
    /////////////////////////////////
 
    function CreateIllusion takes player whichPlayer, integer ID, real dur, real damageDealt, real damageReceived, real x, real y, real angle returns unit
        set illusion = Create( whichPlayer, ID, dur, damageDealt, damageReceived, x, y, angle )
        return illusion
    endfunction
 
    function CopyUnit takes player whichPlayer, unit u, real dur, real damageDealt, real damageReceived, real x, real y, real angle returns unit
        set illusion = Copy( whichPlayer, u, dur, damageDealt, damageReceived, x, y, angle )
        return illusion
    endfunction
 
    function SetIllusionLevel takes unit u, integer level, boolean showEyeCandy returns boolean
        local integer i = GetUnitId( u )
        local integer lastOrder
        local unit tempUnit
        local unit new
        local real x
        local real y
        local boolean success = false
        if check[i] then
            if IsUnitType( u, UNIT_TYPE_HERO ) then
                set x = GetUnitX( u )
                set y = GetUnitY( u )
                set tempUnit = CreateUnit( DUMMY_OWNER, GetUnitTypeId( u ), x, y, GetUnitFacing( u ) )
                set lastOrder = GetUnitCurrentOrder( u )
                call SetHeroLevel( tempUnit, level, false )
                set new = Copy( owner[i], tempUnit, duration[i], damageFactor[i], receiveFactor[i], x, y, GetUnitFacing( u ) )
                set index = 0
                loop
                    set index = index + 1
                    call UnitAddItemToSlotById( new, GetItemTypeId( UnitItemInSlot( u, index ) ), index )
                    exitwhen index == 6
                endloop
                //! runtextmacro REDIRECTDATA( "GetUnitId( u )", "GetWidgetLife( u )*GetWidgetLife( new )/GetUnitState( u, UNIT_STATE_MAX_LIFE )", "GetUnitState( u, UNIT_STATE_MANA )*GetUnitState( new, UNIT_STATE_MANA )/GetUnitState( u, UNIT_STATE_MAX_MANA )" )
                call RemoveUnit( u )
                if showEyeCandy then
                    call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Other\\Levelup\\LevelupCaster.mdl", new, "origin" ) )
                endif
                set success = true
                set tempUnit = null
                set new = null
            debug else
                debug call Debug( ERROR_PREFIX + "Specified illusion is not a hero" )
            endif
        debug else
            debug call Debug( ERROR_PREFIX + "Specified unit is not an illusion created by the system" )
        endif
        return success
    endfunction
 
    //! textmacro DEBUG takes RETURN
    if not check[i] then
        debug call Debug( ERROR_PREFIX + "Specified unit is not an illusion created by the system" )
        $RETURN$
    endif
    //! endtextmacro
 
    function SetIllusionDuration takes unit u, real time returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set duration[i] = time
        return true
    endfunction
 
    function AddIllusionDuration takes unit u, real extraTime returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set duration[i] = duration[i] + extraTime
        return true
    endfunction
 
    function SetIllusionDamageFactor takes unit u, real factor returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set damageFactor[i] = factor
        return true
    endfunction
 
    function SetIllusionReceiveFactor takes unit u, real factor returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set receiveFactor[i] = factor
        return true
    endfunction
 
    function ShowIllusionDeathEffect takes unit u, boolean flag returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set showDeath[i] = flag
        return true
    endfunction
 
    function SetIllusionDeathEffect takes unit u, string model returns boolean
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "return false" )
        set deathSFX[i] = model
        return true
    endfunction
 
    function GetIllusionElapsedTime takes unit u returns real
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "" )
        return elapsed[i]
    endfunction
 
    function GetIllusionRemainingDuration takes unit u returns real
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "" )
        return duration[i] - elapsed[i]
    endfunction
 
    function GetIllusionTotalDuration takes unit u returns real
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "" )
        return duration[i]
    endfunction
 
    function GetIllusionDamageFactor takes unit u returns real
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "" )
        return damageFactor[i]
    endfunction
 
    function GetIllusionReceiveFactor takes unit u returns real
        local integer i = GetUnitId( u )
        //! runtextmacro DEBUG( "" )
        return receiveFactor[i]
    endfunction
 
    function GetLastIllusion takes nothing returns unit
        return illusion
    endfunction
 
    function GetIllusionFlag takes unit u returns boolean
        return check[GetUnitId( u )]
    endfunction
 
    function IllusionDeathEvent takes code c returns nothing
        if illuDeathTrig == null then
            set illuDeathTrig = CreateTrigger()
            call TriggerRegisterVariableEvent( illuDeathTrig, SCOPE_PRIVATE + "illusionDeathEvent", EQUAL, 1 )
        endif
        call TriggerAddCondition( illuDeathTrig, Filter( c ) )
    endfunction
 
 
    ////////////////////////////////////////////////
    // This function adjusts the damage dealt and //
    // taken by the illusions                     //
    ////////////////////////////////////////////////
    private function DamageAdjustment takes nothing returns nothing
        local integer uDex = GetUnitId( PDDS.source )
        local integer tDex = GetUnitId( PDDS.target )
        if check[uDex] and check[tDex] then
            set PDDS.amount = PDDS.amount*damageFactor[uDex]*receiveFactor[tDex]
        elseif check[uDex] then
            set PDDS.amount = PDDS.amount*damageFactor[uDex]
        elseif check[tDex] then
            set PDDS.amount = PDDS.amount*receiveFactor[tDex]
        endif
    endfunction
 
 
    ////////////////////////////////////////////////
    // Registers an illusion death event          //
    ////////////////////////////////////////////////
    private function RefreshDeathTrigger takes nothing returns nothing
        local unit u
        static if LIBRARY_GroupUtils then
            call GroupEnumUnitsInRect( ENUM_GROUP, bj_mapInitialPlayableArea, null )
            loop
                set u = FirstOfGroup( ENUM_GROUP )
                exitwhen u == null
                call GroupRemoveUnit( ENUM_GROUP, u )
                if check[GetUnitId( u )] then
                    call TriggerRegisterUnitStateEvent( deathEvent, u, UNIT_STATE_LIFE, LESS_THAN, UNIT_MIN_LIFE )
                endif
            endloop
        else
            call GroupEnumUnitsInRect( S.tempGroup, bj_mapInitialPlayableArea, null )
            loop
                set u = FirstOfGroup( S.tempGroup )
                exitwhen u == null
                call GroupRemoveUnit( S.tempGroup, u )
                if check[GetUnitId( u )] then
                    call TriggerRegisterUnitStateEvent( deathEvent, u, UNIT_STATE_LIFE, LESS_THAN, UNIT_MIN_LIFE )
                endif
            endloop
        endif
    endfunction
 
 
    ////////////////////////////////////////////////
    // This function is responsible for hiding or //
    // showing the illusion's death SFX           //
    ////////////////////////////////////////////////
    private function OnDeath takes nothing returns nothing
        local unit u = GetTriggerUnit()
        local integer i = GetUnitId( u )
        call ShowUnit( u, false )
        set illusionDeathEvent = 0
        set illusionDeathEvent = 1
        set illusionDeathEvent = 0
        if showDeath[i] then
            call DestroyEffect( AddSpecialEffect( deathSFX[i], GetUnitX( u ), GetUnitY( u ) ) )
        endif
        set usedDeathEvent = usedDeathEvent + 1
        if usedDeathEvent == 30 then
            set usedDeathEvent = 0
            call DestroyTrigger( deathEvent )
            set deathEvent = CreateTrigger()
            call TriggerAddCondition( deathEvent, deathHandler )
            call RefreshDeathTrigger()
        endif
        set u = null
    endfunction
 
 
    ///////////////////////////////////////////////
    // Initialization                            //
    ///////////////////////////////////////////////
    private module M
        static method onInit takes nothing returns nothing
            local code c = function OnDeath
            static if LIBRARY_RegisterPlayerUnitEvent then
                call RegisterPlayerUnitEventForPlayer( EVENT_PLAYER_UNIT_SUMMON, function OnSummon, DUMMY_OWNER )
                call RegisterPlayerUnitEvent( EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, function CacheTargetOrder )
                call RegisterPlayerUnitEvent( EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, function CachePointOrder )
                call RegisterPlayerUnitEvent( EVENT_PLAYER_UNIT_ISSUED_ORDER, function CacheOrder )
            else
                local code c1 = function OnSummon
                local code c2 = function CacheTargetOrder
                local code c3 = function CachePointOrder
                local code c4 = function CacheOrder
                local trigger t1 = CreateTrigger()
                local trigger t2 = CreateTrigger()
                local trigger t3 = CreateTrigger()
                local trigger t4 = CreateTrigger()
                set index = 16
                loop
                    set index = index - 1
                    static if LIBRARY_PlayerUtils then
                        call TriggerRegisterPlayerUnitEvent( t2, GetPlayerById(index), EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, null )
                        call TriggerRegisterPlayerUnitEvent( t3, GetPlayerById(index), EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, null )
                        call TriggerRegisterPlayerUnitEvent( t4, GetPlayerById(index), EVENT_PLAYER_UNIT_ISSUED_ORDER, null )
                    else
                        call TriggerRegisterPlayerUnitEvent( t2, Player(index), EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, null )
                        call TriggerRegisterPlayerUnitEvent( t3, Player(index), EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, null )
                        call TriggerRegisterPlayerUnitEvent( t4, Player(index), EVENT_PLAYER_UNIT_ISSUED_ORDER, null )
                    endif
                    exitwhen index == 0
                endloop
                call TriggerRegisterPlayerUnitEvent( t1, DUMMY_OWNER, EVENT_PLAYER_UNIT_SUMMON, Filter( c1 ) )
                call TriggerAddCondition( t2, Filter( c2 ) )
                call TriggerAddCondition( t3, Filter( c3 ) )
                call TriggerAddCondition( t4, Filter( c4 ) )
            endif
            set deathHandler = Filter( c )
            call TriggerAddCondition( deathEvent, deathHandler )
            call AddDamageHandler( function DamageAdjustment )
            set durationUpdater = function AdjustTimedLife
            set hash = HashTable.create()
            set dummyCaster = CreateUnit( DUMMY_OWNER, DUMMY_ID, 0, 0, 0 )
            set casterItem = UnitAddItemById( dummyCaster, ITEM_ID )
            set localPlayer = GetLocalPlayer()
        endmethod
    endmodule
 
    private struct S extends array
        static if not LIBRARY_GroupUtils then
            static group tempGroup = CreateGroup()
        endif
        implement M
    endstruct
 
 
endlibrary
 

Illusion Editor ObjectMerger

ILLUSION EDITOR OBJECT MERGER

GUI Support

Code: jass

library IllusionEditorGUISupport uses IllusionEditor
 
 
    private function Operate takes nothing returns nothing
        if udg_IE_Operation == 0 then
            set udg_IE_Illusion = GetLastIllusion()
            return
        elseif udg_IE_Operation == udg_IE_CreateIllusion then
            set udg_IE_Illusion = CreateIllusion( udg_IE_Owner, udg_IE_UnitType, udg_IE_Duration, udg_IE_DamageDealtFactor, udg_IE_DamageReceiveFactor, GetLocationX( udg_IE_Position ), GetLocationY( udg_IE_Position ), udg_IE_Facing )
            set udg_IE_Operation = 0
            set udg_IE_Owner = null
            set udg_IE_UnitType = 0
            set udg_IE_Duration = 0.00
            set udg_IE_DamageDealtFactor = 0.00
            set udg_IE_DamageReceiveFactor = 0.00
            set udg_IE_Facing = 0.00
            return
        elseif udg_IE_Operation == udg_IE_CopyUnit then
            set udg_IE_Illusion = CopyUnit( udg_IE_Owner, udg_IE_BaseUnit, udg_IE_Duration, udg_IE_DamageDealtFactor, udg_IE_DamageReceiveFactor, GetLocationX( udg_IE_Position ), GetLocationY( udg_IE_Position ), udg_IE_Facing )
            set udg_IE_Operation = 0
            set udg_IE_Owner = null
            set udg_IE_BaseUnit = null
            set udg_IE_Duration = 0.00
            set udg_IE_DamageDealtFactor = 0.00
            set udg_IE_DamageReceiveFactor = 0.00
            set udg_IE_Facing = 0.00
            return
        elseif udg_IE_Operation == udg_IE_SetLevel then
            set udg_IE_Flag = SetIllusionLevel( udg_IE_Illusion, udg_IE_NewLevel, udg_IE_Flag )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_SetDuration then
            set udg_IE_Flag = SetIllusionDuration( udg_IE_Illusion, udg_IE_Duration )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_AddDuration then
            set udg_IE_Flag = AddIllusionDuration( udg_IE_Illusion, udg_IE_Duration )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_SetDamageFactor then
            set udg_IE_Flag = SetIllusionDamageFactor( udg_IE_Illusion, udg_IE_DamageDealtFactor )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_SetReceiveFactor then
            set udg_IE_Flag = SetIllusionReceiveFactor( udg_IE_Illusion, udg_IE_DamageReceiveFactor )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_ShowDeathEffect then
            set udg_IE_Flag = ShowIllusionDeathEffect( udg_IE_Illusion, udg_IE_Flag )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_SetDeathEffect then
            set udg_IE_Flag = SetIllusionDeathEffect( udg_IE_Illusion, udg_IE_DeathEffect )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_GetRemainingDuration then
            set udg_IE_Duration = GetIllusionRemainingDuration( udg_IE_Illusion )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_GetTotalDuration then
            set udg_IE_Duration = GetIllusionTotalDuration( udg_IE_Illusion )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_GetDamageFactor then
            set udg_IE_DamageDealtFactor = GetIllusionDamageFactor( udg_IE_Illusion )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_GetReceiveFactor then
            set udg_IE_DamageReceiveFactor = GetIllusionReceiveFactor( udg_IE_Illusion )
            set udg_IE_Operation = 0
            return
        elseif udg_IE_Operation == udg_IE_GetFlag then
            set udg_IE_Flag = GetIllusionFlag( udg_IE_Illusion )
            set udg_IE_Operation = 0
            return
        endif
    endfunction
 
    hook DoNothing Operate
 
 
endlibrary
 
 
function InitTrig_GUI_Support takes nothing returns nothing
    /* We use an InitTrig function instead of a scope/library
    initializer to initialize the values of our variables to
    make sure that InitGlobals() runs first so that the values
    of our variables would not be reset.                    */
    call Trig_GUI_IllusionEditor_Documentation_Actions.execute()
endfunction
 

GUI Support Documentation

GUI IllusionEditor Documentation
    Events
    Conditions
    Actions
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- |||||||||||||||||||||||||||||||||||||||||||||||||              GUI ILLUSION EDITOR GUIDE              |||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- First you need to choose what operation you want to do using the system. Like this:             --------
        Set IE_Operation = IE_CreateIllusion
        -------- It can be any from the list below:                                                                                             --------
        --------                                                                                                                                                 --------
        -------- 1. CreateIllusion - creates an illusion of a certain unit-type.                                                      --------
        -------- 2. CopyUnit - creates a mirror image of a unit which possesses the same items and abilities   --------
        --------                      as the original unit.                                                                                             --------
        -------- 3. SetLevel - sets the level of a hero type illusion to a desired value.                                      --------
        -------- 4. SetDuration - sets the total duration of an illusion to a desired value, if the given amount   --------
        --------                          is less than the elapsed time of the illusion, it will be destroyed.                      --------
        -------- 5. AddDuration - adds an extra time to an illusion's duration.                                                   --------
        -------- 6. SetDamageFactor - sets the damage dealt factor of an illusion.                                          --------
        -------- 7. SetReceiveFactor - sets the damage receive factor of an illusion                                       --------
        -------- 8. ShowDeathEffect - shows/hides the death effect of an illusion.                                         --------
        -------- 9. SetDeathEffect - sets a new special effect to replace the default death effect of an          --------
        --------                                 illusion.                                                                                                    --------
        -------- 10. GetRemainingDuration - gets the remaining duration of an illusion.                                   --------
        -------- 11. GetTotalDuration - gets the total duration of an illusion.                                                    --------
        -------- 12. GetDamageFactor - gets the damage dealt factor of an illusion.                                       --------
        -------- 13. GetReceiveFactor - gets the damage receive factor of an illusion.                                   --------
        -------- 14. GetFlag - checks if the illusion was created using this system or not.                                --------
        --------                                                                                                                                                 --------
        -------- Next, you have to setup all the data necessary for the operation you chose. Below are the   --------
        -------- list of data needed for each operation (Note that all these have an IE_ prefix):                       --------
        --------                                                                                                                                                 --------
        -------- 1. - Owner                                                                                                                                --------
        --------     - UnitType                                                                                                                            --------
        --------     - Duration                                                                                                                             --------
        --------     - DamageDealtFactor                                                                                                           --------
        --------     - DamageReceiveFactor                                                                                                      --------
        --------     - Position                                                                                                                              --------
        --------     - Facing                                                                                                                                --------
        --------                                                                                                                                                 --------
        -------- 2. - Owner                                                                                                                                --------
        --------     - BaseUnit                                                                                                                            --------
        --------     - Duration                                                                                                                             --------
        --------     - DamageDealtFactor                                                                                                           --------
        --------     - DamageReceiveFactor                                                                                                      --------
        --------     - Position                                                                                                                              --------
        --------     - Facing                                                                                                                                --------
        --------                                                                                                                                                 --------
        -------- 3. - Illusion                                                                                                                               --------
        --------     - NewLevel                                                                                                                          --------
        --------     - Flag                                                                                                                                   --------
        --------                                                                                                                                                 --------
        -------- 4, 5. - Illusion                                                                                                                           --------
        --------         - Duration                                                                                                                         --------
        --------                                                                                                                                                 --------
        -------- 6. - Illusion                                                                                                                               --------
        --------     - DamageDealtFactor                                                                                                          --------
        --------                                                                                                                                                 --------
        -------- 7. - Illusion                                                                                                                               --------
        --------     - DamageReceiveFactor                                                                                                     --------
        --------                                                                                                                                                 --------
        -------- 8. - Illusion                                                                                                                               --------
        --------     - Flag                                                                                                                                   --------
        --------                                                                                                                                                 --------
        -------- 9. - Illusion                                                                                                                               --------
        --------     - DeathEffect                                                                                                                       --------
        --------                                                                                                                                                 --------
        -------- 10, 11, 12, 13, 14. - Illusion                                                                                                     --------
        --------                                                                                                                                                 --------
        -------- The example we chose is CreateIllusion operation. So as you can see in number 1, we         --------
        -------- need to setup those variables so now we do:                                                                          --------
        Set IE_Owner = Player 1 (Red)
        Set IE_UnitType = Mortar Team
        Set IE_Duration = 5.00
        Set IE_DamageDealtFactor = 0.35
        Set IE_DamageReceiveFactor = 4.00
        Set IE_Position = (Center of (Playable map area))
        Set IE_Facing = Default building facing
        --------                                                                                                                                                 --------
        -------- And finally, what we have to do is execute the operation which in this case is very simple.    --------
        -------- To execute the opertation we have to use this:                                                                       --------
        Do nothing
        -------- Easy right? Plus we are also able to add a new functionality to the previously useless            --------
        -------- <Do nothing> function. ^-^                                                                                                      --------
        --------                                                                                                                                                 --------
        --------                                                                                                                                                 --------
        --------  ======================================================================= --------
        --------                                                                                                                                                 --------
        --------                                                                                                                                                 --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||              CONSTANTS SETTING              ||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        Set IE_CreateIllusion = 1
        Set IE_CopyUnit = 2
        Set IE_SetLevel = 3
        Set IE_SetDuration = 4
        Set IE_AddDuration = 5
        Set IE_SetDamageFactor = 6
        Set IE_SetReceiveFactor = 7
        Set IE_ShowDeathEffect = 8
        Set IE_SetDeathEffect = 9
        Set IE_GetRemainingDuration = 10
        Set IE_GetTotalDuration = 11
        Set IE_GetDamageFactor = 12
        Set IE_GetReceiveFactor = 13
        Set IE_GetFlag = 14
        --------                                                                                                                                                 --------
        --------                                                                                                                                                 --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        -------- Do not enable the following line. However, they are variable creators so do not delete them. --------
        -------- ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||| --------
        Set IE_Operation = 0
        Set IE_NewLevel = 0
        Set IE_DamageDealtFactor = 0.00
        Set IE_DamageReceiveFactor = 0.00
        Set IE_Duration = 0.00
        Set IE_Facing = 0.00
        Set IE_Illusion = No unit
        Set IE_Owner = Player 1 (Red)
        Set IE_UnitType = No unit-type
        Set IE_BaseUnit = No unit
        Set IE_Position = IE_Position
        Set IE_Flag = False
        Set IE_DeathEffect =  
        --------  ======================================================================= --------

moyack · **Reply #1 on:** August 24, 2016, 06:43:20 AM

WElcome AGD to Blizzmod:

I'll try to get some time to check your system to give you some feedback. I've fixed some stuff in order to get a better presentation in the post.

HUGSS!!!

AGD · **Reply #2 on:** August 25, 2016, 06:59:55 AM

Quote

WElcome AGD to Blizzmod:

I'll try to get some time to check your system to give you some feedback. I've fixed some stuff in order to get a better presentation in the post.

HUGSS!!!

Thanks =) Btw, documentation was updated.

AGD · **Reply #3 on:** September 08, 2016, 07:38:01 AM

Updated to v1.3

- Added some optional library requirements including TimerUtils, GroupUtils, PlayerUtils
- Simplified some script sections
- Added the API for registering an illusion death event
- Fixed a bug in the previous version where illusions' death effect visibility are not properly managed
- Updated the demo spell
- Added a new API GetIllusionElapsedTime() for getting the elapsed time of an illusion
- Shortened the function AdjustTimedLife
- Removed some unnecessary extra return values when in debug mode in the public functions
- Some other code restructuring and some other fixes