Recent Posts

Related Topics or Resources

[snippet] AllocLoop (AKA Alloc 2)
by moyack

Creep Respawn

It used to re-spawn a creep.

Code: jass

library CreepRespawn /* v1.0.0.2
*************************************************************************************
*
*   An RPG Creep Respawn.
*
*************************************************************************************
*
*   */ needs /*
*
*       ___________________________________
*
*       Required:
*
*       */ Table                                    /*      hiveworkshop.com/threads/snippet-new-table.188084/
*       */ TimerUtils                               /*      wc3c.net/showthread.php?t=101322
*       */ Alloc                                    /*      github.com/nestharus/JASS/blob/master/jass/Systems/Alloc/Table/script.j
*
*       ___________________________________
*
*       Optional:
*
*       */ optional RegisterPlayerUnitEvent         /*      hiveworkshop.com/threads/snippet-registerevent-pack.250266/
*       */ optional UnitDex                         /*      hiveworkshop.com/threads/system-unitdex-unit-indexer.248209/
*
************************************************************************************
*
*   SETTINGS
*
*/
    globals
        /*
        *    Player
        */
        private constant   player PLAYER                 = Player(PLAYER_NEUTRAL_AGGRESSIVE)
        
        /*
        *    Special effect for revived creep.
        */
        private constant   string REVIVE_EFFECT          = "Abilities\\Spells\\Human\\Resurrect\\ResurrectTarget.mdl"
 
        /*
        *    Revive duration
        */
        private constant     real CREEP_REGULAR_DURATION = 5
        private constant     real CREEP_BOSS_DURATION    = 10
        
        /*
        *   Boss Type
        *
        *   Note: You must set the Unit's classification at Object Editor
        *         based on CREEP_TYPE_BOSS.
        */
        private constant unittype CREEP_TYPE_BOSS        = UNIT_TYPE_ANCIENT
 
        /*
        *    Maximum number of creeps.
        *
        *   Note: You do not need to change this value unless you know what
        *   are you doing.
        */
        private constant  integer CREEP_MAX_COUNT        = 0x2000
    endglobals
/*
***********************************************************************************/
 
    globals
        private TableArray CreepTable
        private integer Count = 0
    endglobals
 
    private struct System extends array
        implement Alloc
 
        private integer type
        private unit unit
        private integer key
 
        private static method onRevive takes nothing returns nothing
            local timer Timer = GetExpiredTimer()
            local thistype this = GetTimerData(Timer)
 
            local unit Creep = CreateUnit(PLAYER,                           /*
            */     this.type,                                               /*
            */     CreepTable[this.key].real[0],                            /*
            */     CreepTable[this.key].real[1],                            /*
            */     CreepTable[this.key].real[2]                             /*
            */ )
            
            static if LIBRARY_UnitDex then
                local integer Index = GetUnitId(Creep)
 
                /*
                *    Copy the old unit's information to new indexed unit.
                */
                set CreepTable[Index].real[0] = CreepTable[this.key].real[0]
                set CreepTable[Index].real[1] = CreepTable[this.key].real[1]
                set CreepTable[Index].real[2] = CreepTable[this.key].real[2]
                set CreepTable[Index].boolean[3] = true
 
                /*
                *    Flush old unit.
                */
                call CreepTable[this.key].flush()
            else
                /*
                *    Set the new unit's index based on dead unit's index
                */
                call SetUnitUserData(Creep, this.key)
            endif
 
            /*
            *    Revive Effect
            */
            call DestroyEffect(AddSpecialEffect(                            /*
            */     REVIVE_EFFECT, GetUnitX(Creep), GetUnitY(Creep)          /*
            */ ))
            
            /*
            *    Remove corpse
            */
            if this.unit != null then
                call RemoveUnit(this.unit)
                set this.unit = null
            endif
            
            /*
            *    Remove Timer
            */
            call ReleaseTimer(Timer)
 
            /*
            *    Remove memory leaks
            */
            set Creep = null
            set Timer = null
            set this.type = 0
            set this.key = 0
            
            /*
            *    Deindex
            */
            call this.deallocate()
        endmethod
        
    static if LIBRARY_RegisterAnyPlayerUnitEvent then
        private static method onDeath takes nothing returns nothing
    else
        private static method onDeath takes nothing returns boolean
    endif
            local thistype this
            local real Duration = 0
            local unit u = GetTriggerUnit()
            local integer k = GetUnitUserData(u)
 
            /*
            *    Check if this unit is registered on this system else it
            *   won't respawn.
            */
            if CreepTable[k].boolean[3] then
                set this = thistype.allocate()
 
                set this.unit = u
                set this.type = GetUnitTypeId(this.unit)
                set this.key = k
 
                if IsUnitType(this.unit, CREEP_TYPE_BOSS) then
                    set Duration = CREEP_BOSS_DURATION
                else
                    set Duration = CREEP_REGULAR_DURATION
                endif
 
                call TimerStart(NewTimerEx(this), Duration, false,          /*
                */     function thistype.onRevive                           /*
                */ )
            debug else
                debug call BJDebugMsg(GetUnitName(u) + " >> false ")
            endif
 
            set u = null
 
            static if not LIBRARY_RegisterAnyPlayerUnitEvent then
                return false
            endif
        endmethod
 
        private static method enumGroup takes nothing returns boolean
            local unit Enum = GetFilterUnit()
 
            /*
            *    Indexing
            */
            static if LIBRARY_UnitDex then
                set Count = GetUnitId(Enum)
            else
                set Count = Count + 1
                call SetUnitUserData(Enum, Count)
            endif
 
            /*
            *    Store a data to CreepTable
            */
            set CreepTable[Count].real[0] = GetUnitX(Enum)
            set CreepTable[Count].real[1] = GetUnitY(Enum)
            set CreepTable[Count].real[2] = GetUnitFacing(Enum)
            set CreepTable[Count].boolean[3] = true
 
            /*
            *    Remove memory leak
            */
            set Enum = null
            return false
        endmethod
 
        private static method registerMode takes nothing returns nothing
            local group Iterator = CreateGroup()
 
            /*
            *    Enumerate all of Player Creep's units
            */
            call GroupEnumUnitsOfPlayer(Iterator, PLAYER, Filter(           /*
            */     function thistype.enumGroup                              /*
            */ ))
 
            /*
            *    Remove memory leaks
            */
            call DestroyGroup(Iterator)
            call DestroyTimer(GetExpiredTimer())
            set Iterator = null
        endmethod
 
        private static method onInit takes nothing returns nothing
            /*
            *    Init Death Event
            */
            static if LIBRARY_RegisterAnyPlayerUnitEvent then
                call RegisterPlayerUnitEvent(PLAYER,                        /*
                */     EVENT_PLAYER_UNIT_DEATH, function thistype.onDeath   /*
                */ )
            else
                local trigger trg = CreateTrigger()
 
                call TriggerRegisterPlayerUnitEvent(trg, PLAYER,            /*
                */     EVENT_PLAYER_UNIT_DEATH, null                        /*
                */ )
                call TriggerAddCondition(trg, Condition(                    /*
                */     function thistype.onDeath                            /*
                */ ))
 
                set trg = null
            endif
 
            /*
            *    Init CreepTable
            */
            set CreepTable = TableArray[CREEP_MAX_COUNT]
 
            /*
            *    Init Register Mode
            */
            call TimerStart(CreateTimer(), 0, false, function thistype.registerMode)
        endmethod
    endstruct
endlibrary

How to install:

Copy this script and all required libraries and paste them to your map.
Done.

Future plans

Warcraft III Projects / Re: Invasions

« Last post by Soahk on June 23, 2019, 03:30:45 AM »

This map is the one with which i have learnt to use Wordleditor, so, i have worked on it for quite a long time, but i have seriously been working on it for several months. Precisely, I started to do it three years ago, but i made so much errors in developping the map that i had to start it again from scratch various times (more parrticularly, i made and remade the terrain various times).

I am still balancing the units' strength, but in theory, it is quite well balanced (thanks to some calculations based on other games i met on B.net). It is in theory because it have not really tested it in game, but when i made units fighting against themselves with an AI, it was good.

But balancing it would be easy, as i can add many content in this map to improve humans or invaders (there is no hero for instance, and heros can make the difference).

Warcraft III Projects / Re: Invasions

« Last post by moyack on June 22, 2019, 09:18:12 PM »

Hi @Soahk

Welcome to wc3 modding.

Quote from: Soahk on June 22, 2019, 03:11:25 AM

This is just a map, named Invasion. The downloading link is here : https://www.epicwar.com/maps/294825/

Hmm, I'll try it when I have time.... and friends to test it.

How long have you been working with your map?

Quote

Basically, it's a mix of assault-defense game, with two sides, humans and invaders, and of strategy game.

Humans' goal is to resist to invaders, and also to throw them away of the map. You can stay in your base, by defending it with walls, towers, and so on, just like a basic defense game. But you can also resist thanks to your army, without walls, and leave your base once you threw invaders back to conquer the world.

Invaders'' goal is simple : kill everyone with your armies. Invaders are overwhelming humans in number of units, but they are controlled by less players, so that they have a worse microgestion than humans. There a 2 kinds of invaders : Fiends and Aliens.

Are you still balancing the gameplay? Is there some gameplay recorded to see how's the game??

Quote

Don't worry about the terrain being very (maybe too) casual. It is something fixable, and I want to make a well-balanced game before terraining.

Fiends :

Humans :

[/quote]About terraining, well, probably for the kind of game is valid to have a "basic" space for the game, but a good terrain can put motivation and interest for your map. I'll definitely will check.

Warcraft III Projects / Invasions

« Last post by Soahk on June 22, 2019, 03:11:25 AM »

This is just a map, named Invasion. The downloading link is here : https://www.epicwar.com/maps/294825/

Basically, it's a mix of assault-defense game, with two sides, humans and invaders, and of strategy game.

Humans' goal is to resist to invaders, and also to throw them away of the map. You can stay in your base, by defending it with walls, towers, and so on, just like a basic defense game. But you can also resist thanks to your army, without walls, and leave your base once you threw invaders back to conquer the world.

Invaders'' goal is simple : kill everyone with your armies. Invaders are overwhelming humans in number of units, but they are controlled by less players, so that they have a worse microgestion than humans. There a 2 kinds of invaders : Fiends and Aliens.

Don't worry about the terrain being very (maybe too) casual. It is something fixable, and I want to make a well-balanced game before terraining.

Fiends :

Humans :